Excel VBA – Email Does not Send When Computer is Locked

calendar_today Asked Apr 18, 2012
thumb_up 16 upvotes
history Updated April 16, 2026

Question posted 2012 · +8 upvotes

I’m having problems sending outlook emails using Excel VBA. I have the code to do it – Sendupdate – and it works fine when I manually run the macro. My second macro StartTimer is intended to execute the above at a set time when I am not at my desk.

However, when the computer is locked the email does not send. When I come back to my desk the email is hanging there as a draft, and I need to click the send button.

Here is my code:

Sub SendUpdate()
Recipient = "[email protected]"
Subj = "update"
Dim msg As String
msg = "hello”

HLink = "mailto:" & Recipient & "?"
HLink = HLink & "subject=" & Subj & "&"
HLink = HLink & "body=" & msg
ActiveWorkbook.FollowHyperlink (HLink)
    Application.Wait (Now + TimeValue("0:00:01"))
    Application.SendKeys "%s"
End Sub

Sub StartTimer()
Application.OnTime TimeValue("18:00:00"), "SendUpdate"

End Sub

Is there a way to code the macro to make sure the email gets pushed?

Accepted answer +16 upvotes

I will break this “Tutorial” in 3 steps

1) Writing your Excel Macro

2) Preparing your vbscript file

3) Setting the task in Windows Task Scheduler

WRITING THE EXCEL MACRO

Open a new File in Excel and in the module, paste this code

Option Explicit

Const strTo As String = "[email protected]"
Const strCC As String = "[email protected]"  '<~~ change "[email protected]" to "" if you do not want to CC
Const strBCC As String = "[email protected]" '<~~ change "[email protected]" to "" if you do not want to BCC

Sub Sample()
    Dim OutApp As Object, OutMail As Object
    Dim strbody As String, strSubject As String

    strSubject = "Hello World"
    strbody = "This is the message for the body"

    Set OutApp = CreateObject("Outlook.Application")

    Set OutMail = OutApp.CreateItem(0)

    On Error Resume Next
    With OutMail
        .To = strTo
        .CC = strCC
        .BCC = strBCC
        .Subject = "This is the Subject line"
        .Body = strbody
        .Send
    End With
    On Error GoTo 0

    Set OutMail = Nothing
    Set OutApp = Nothing
End Sub

Save the Excel File as C:Tester.Xlsm if you are using Excel 2007 onwards or C:Tester.Xls if you are using Excel 2003 and exit

PREPARING THE VBSCRIPT FILE

Open Notepad and then paste this code. Change the extension “.xls” as applicable.

Dim xlApp
Dim xlBook

Set xlApp = CreateObject("Excel.Application")
Set xlBook = xlApp.Workbooks.Open("C:Tester.xls", 0, True)
xlApp.Run "Sample"
xlBook.Close
xlApp.Quit

Set xlBook = Nothing
Set xlApp = Nothing

Save the File as Tester.vbs and close it

enter image description here

SETTING UP THE TASK IN WINDOWS TASK SCHEDULER

Could you confirm your windows operating system? – Siddharth Rout 36 mins ago

Windows XP. Its my work computer (so has the usual logins etc). – keynesiancross 18 mins ago

Click on the Start Button | All Programs | Accessories | System Tools | Schedule Tasks to get this window

enter image description here

Double click on “Add Scheduled Task” to get this window

enter image description here

Click Next

enter image description here

Click on “Browse” and select the vbs file that we created earlier and click on “open”

The next window that you get is crucial as it is here we need to mention when script needs to run

enter image description here

After you have done the needful, click on next.

enter image description here

In this window, enter your login details so that the script can run even when your screen is locked.

Click “Next” when done and then click “Finish” in the next window. Your task scheduler now looks like this

enter image description here

And you are done

Lock your pc and go take a coffee break 😉 When you come back (depending on what time you set in the task scheduler and how much time is your break), the email would have been sent.

HTH

2 code variants in this answer

  • Variant 1 — 31 lines, starts with Option Explicit
  • Variant 2 — 11 lines, starts with Dim xlApp

Top excel-vba Q&A (6)

+16 upvotes ranks this answer #27 out of 136 excel-vba solutions on this site — top 20%.
excel-vba